LocalStackでEC2を構築する

docker pull ubuntu:lunar

docker tag ubuntu:lunar localstack-ec2/ubuntu-focal-ami:ami-000001

# AWSプロバイダの設定。LocalStackを指すためにカスタムエンドポイントを使用。
provider "aws" {
  region                      = "us-east-1" # 使用するリージョンを指定
  access_key                  = "mock_access_key" # LocalStackではダミーのアクセスキーを使用
  secret_key                  = "mock_secret_key" # LocalStackではダミーのシークレットキーを使用
  skip_credentials_validation = true # ローカル環境のため、クレデンシャル検証をスキップ
  skip_metadata_api_check     = true # メタデータAPIのチェックをスキップ
  skip_requesting_account_id  = true # アカウントIDのリクエストをスキップ
  endpoints {
    ec2 = "http://localhost:4566" # LocalStackのエンドポイント設定
  }
}

# VPCリソースの作成
resource "aws_vpc" "example_vpc" {
  cidr_block = "10.0.0.0/16" # VPCのCIDRブロックを指定
}

# ネットワークACLリソースの作成
resource "aws_network_acl" "example_acl" {
  vpc_id = aws_vpc.example_vpc.id # 上で作成したVPCに紐付け

  # アウトバウンドルールの設定
  egress {
    action     = "allow" # トラフィックを許可
    protocol   = "-1" # すべてのプロトコルを指定
    rule_no    = 100 # ルール番号
    cidr_block = "0.0.0.0/0" # すべてのIP範囲を指定
    from_port  = 0 # すべてのポートを指定
    to_port    = 0 # すべてのポートを指定
  }

  # インバウンドルールの設定
  ingress {
    action     = "allow" # トラフィックを許可
    protocol   = "-1" # すべてのプロトコルを指定
    rule_no    = 100 # ルール番号
    cidr_block = "0.0.0.0/0" # すべてのIP範囲を指定
    from_port  = 0 # すべてのポートを指定
    to_port    = 0 # すべてのポートを指定
  }

  # タグの設定
  tags = {
    Name = "example_acl" # タグ名
  }
}

# サブネットの作成
resource "aws_subnet" "example_subnet" {
  vpc_id     = aws_vpc.example_vpc.id # 上で作成したVPCに紐付け
  cidr_block = "10.0.1.0/24" # サブネットのCIDRブロックを指定

  tags = {
    Name = "example_subnet" # タグ名
  }
}



/* SubnetにACL設定をすることはLocakStackでは未対応らしい
resource "aws_network_acl_association" "example_association" {
  subnet_id      = aws_subnet.example_subnet.id # 上で作成したサブネットを指定
  network_acl_id = aws_network_acl.example_acl.id # 上で作成したネットワークACLを指定
}
*/

# SSH接続を許可するセキュリティグループの作成
resource "aws_security_group" "allow_ssh" {
  name        = "allow_ssh"
  description = "Allow SSH inbound traffic"
  vpc_id      = aws_vpc.example_vpc.id

  # SSH接続を許可するインバウンドルール
  ingress {
    from_port   = 22
    to_port     = 22
    protocol    = "tcp"
    cidr_blocks = ["0.0.0.0/0"]
  }

  # すべてのアウトバウンドトラフィックを許可
  egress {
    from_port   = 0
    to_port     = 0
    protocol    = "-1"
    cidr_blocks = ["0.0.0.0/0"]
  }
}

# EC2インスタンスにセキュリティグループを関連付け
resource "aws_instance" "example_ec2" {
  ami                    = "ami-000001"
  instance_type          = "t2.micro"
  subnet_id              = aws_subnet.example_subnet.id
  vpc_security_group_ids = [aws_security_group.allow_ssh.id]

  tags = {
    Name = "example_instance1"
  }
}